* easy-Cの入門書 [レベル19]
-(by [[K]], 2025.09.16)

--目次はこちら → [[a23_intro00]]

** ノート
 がめんを左に1れつずらす → GSCROLL(19,19,1,1,-1,0);
 なし

** もんだい
-[19-1] マリコちゃんゲームを作ります
 スーパーマリオみたいなゲームを作りたいなってかんがえました。
 でも、がめんをうごかしたり、てきをうごかしたりするのはたいへんです。
 さらにマリオではよくおちてしぬので、おちてもしなないゲームにしたいです。
--Gは「げんき」です。
--Bははいけいの色、XとYはじぶんのいち、Jはジャンプ中かどうか、です。
 ECHWIN(32,24); B=3;                                                 ← がめんのひろさは、32x24
 ECHBOX(32,24,0,0,0,0,B);                                            ← がめんをぜんぶけす
 FOR (I=2; I<=22; I=I+5) { ECHBOX(32,1,0,I,1,4,0); }                 ← じめんを5ほんかく
 FOR (I=0; I<12; I=I+1) { ECHBOX(2,1,RND(5)*5+6,RND(3)*5+7,0,0,B); } ← じめんにあなをあける
 FOR (I=0; I<16; I=I+1) { ECH(RND(26)+4,RND(19)+3,3,0,B); }          ← バツをおく
 FOR (I=0; I<16; I=I+1) { ECH(RND(26)+4,RND(19)+3,2,6,B); }          ← コインをおく
 G=1000; X=0; Y=21; J=0;                                             ← スタートちてん
 FOR (;;) {
   GPRINTF(0,0,0,B,"GENKI=%05d",G);                                    ← [もんだい]これはなにかな？
   ECH(X,Y,6,7,B);                                                     ← じぶんをかく
   IF (G<=0) { ECH(X,Y,6,5,B); BREAK; }                                ← [もんだい]これはなにかな？
   IF (Y<=6 && X==31) { GPRINTF(23,0,2,0," << CLEAR !! >> "); BREAK; } ← [もんだい]これはなにかな？
   WAIT(200); I=INKEY(1);                                              ← [もんだい]これはなにかな？
   ECH(X,Y,0,0,B);                                                     ← じぶんをけす
   IF (I!=32) { J=0; }                                                 ← ジャンプボタンをおしてなかったら、J=0
   IF (Y%5==3) { J=0; }                                                ← たかくとんだら、J=0
   IF (I==32 && GETECH(X,Y+1)==1) { J=1; }                             ← ジャンプボタンをおしてる&&じぶんの下はじめん、ならJ=1
   IF (I==27) { G=0; }                                                 ← ゲームをやめるボタンをおしたら、G=0
   X=X+1;                                                              ← 右にいっぽすすむ
   IF (X==32) { X=0; Y=Y-5; }                                          ← 右はじについたら、上のだんの左はじへ
   Y=Y-J;                                                              ← J=1だったら、1つ上のマスへ
   IF (J==0 && GETECH(X,Y+1)!=1) { Y++; }                              ← ジャンプしてなくて、下がじめんじゃない、なら下にすすむ
   G=G-1;                                                              ← [もんだい]これはなにかな？
   IF (GETECH(X,Y)==3) { G=G-400; }                                    ← [もんだい]これはなにかな？
   IF (GETECH(X,Y)==2) { G=G+200; }                                    ← [もんだい]これはなにかな？
   IF (G<0) { G=0; }                                                   ← [もんだい]これはなにかな？
 }
トップ   編集 差分 バックアップ 添付 複製 名前変更 リロード   新規 一覧 単語検索 最終更新   ヘルプ   最終更新のRSS