a24_picoTrain1 のバックアップ(No.3)

バックアップ一覧
差分を表示
現在との差分を表示
ソースを表示
a24_picoTrain1 へ行く。
- 1 (2024-10-22 (火) 11:37:58)
- 2 (2024-10-22 (火) 13:17:16)
- 3 (2024-10-22 (火) 18:04:45)
- 4 (2024-10-22 (火) 22:32:05)
- 5 (2024-10-22 (火) 22:32:05)
- 6 (2024-10-22 (火) 22:32:05)

Raspberry Pi Pico で鉄道模型を動かす

(by K, 2024.10.22)

↑

(0) 目的

小学生にプログラミングを教えようとしても、画面の中でピコピコと動くだけではたいして興味を示さない（場合がある）。
そんな場合は、おもちゃをPCから制御すればきっと喜んでやる気を出す。
よし鉄道模型を動かそう！

もし鉄道模型とラズパイピコと電源アダプタを持っていれば、追加で必要な費用はたったの1230円程度です！（単品では買えないものもあるので、実質的にはもうちょっとかかりますが）

↑

(1) pico側に書き込んだスケッチ

#include <hardware/pwm.h>

void pico_analogWriteFreqRang(int pin, float freq, uint32_t rang)
// rang=[0,65535], freq > 125000000.0 / (rang + 1) / 256
// slice0: GP0,  GP1,  GP16, GP17
// slice1: GP2,  GP3,  GP18, GP19
// slice2: GP4,  GP5,  GP20, GP21
// slice3: GP6,  GP7,  GP22
// slice4: GP8,  GP9,  GP25
// slice5: GP10, GP11, GP26, GP27
// slice6: GP12, GP13, GP28
// slice7: GP14, GP15
// [註]sliceが同じものは、freqとrangは共通になる.
{
    int slice_num = pwm_gpio_to_slice_num(pin);
    float tmp = (rang + 1) * freq;
    gpio_set_function(pin, GPIO_FUNC_PWM);
    pwm_set_clkdiv(slice_num, 125000000.0 / tmp); // 256未満.
    pwm_set_wrap(slice_num, rang);
}

void pico_analogWrite(int pin, uint32_t val)
{
    int slice_num = pwm_gpio_to_slice_num(pin);
    pwm_set_chan_level(slice_num, pin & 1, val);
    pwm_set_enabled(slice_num, true);
}

void setup() { Serial.begin(115200); }

int prm_f0[4][4], prm_f1[16][4], prm_f2[3] = { A0, A1, A2 };
int prms[8] = { 4, 4, 1, 0, 1, 2, 1, 1 };

void loop()
{
    int c = Serial.read(), ch, p[8], dir, i, j;
    if (c < 0) { delay(3); }
    if (0xf0 <= c && c <= 0xf7) {
        j = prms[c - 0xf0];
        for (i = 0; i < j; i++) {
            while (Serial.available() < 1) {}
            p[i] = Serial.read();
        }
        ch = p[0] & 63;
        dir = (p[0] >> 6) & 3;
    }
    if (c == 0xf0 && 0 <= ch && ch <= 3) {
        prm_f0[ch][0] = p[1]; pinMode(p[1], OUTPUT);
        prm_f0[ch][1] = p[2]; pinMode(p[2], OUTPUT);
        prm_f0[ch][2] = p[3]; pinMode(p[3], OUTPUT);
        pico_analogWriteFreqRang(p[1], 100 * 1000, 255); // 100KHz
        pico_analogWrite(p[1], 0);
        digitalWrite(p[2], LOW);
        digitalWrite(p[3], LOW);
    }
    if (c == 0xf1 && 0 <= ch && ch <= 15) {
        prm_f1[ch][0] = p[1];
        prm_f1[ch][1] = p[2]; pinMode(p[2], OUTPUT);
        prm_f1[ch][2] = p[3]; pinMode(p[3], OUTPUT);
        digitalWrite(p[2], LOW);
        digitalWrite(p[3], LOW);
    }
    if (c == 0xf4 && 0 <= ch && ch <= 3) {
        digitalWrite(prm_f0[ch][1],  dir       & 1);
        digitalWrite(prm_f0[ch][2], (dir >> 1) & 1);
    }
    if (c == 0xf5 && 0 <= ch && ch <= 3) {
        pico_analogWrite(prm_f0[ch][0], p[1]);
    }
    if (c == 0xf6 && 0 <= ch && ch <= 15) {
        digitalWrite(prm_f1[ch][1],  dir       & 1);
        digitalWrite(prm_f1[ch][2], (dir >> 1) & 1);
        delay(prm_f1[ch][0] * 8); // max 2.0sec.
        digitalWrite(prm_f1[ch][1], LOW);
        digitalWrite(prm_f1[ch][2], LOW);
    }
    if (c == 0xf7 && 0 <= ch && ch <= 2) {
        i = analogRead(prm_f2[ch]);
        Serial.write((i >> 8) & 255);
        Serial.write( i       & 255);
    }
}

↑

(2) 使っているパーツ類

[1個1000円程度] Raspberry Pi Pico
[2個1000円程度] L298N モジュール（たとえば https://www.amazon.co.jp/dp/B09TJZ953V/ ）
[1個1900円程度] マルチ電圧アダプター（5V～15V）（たとえば https://www.amazon.co.jp/gp/product/B08Q3T61M6/ ）
[10個400円程度] CdSフォトレジスタ type:5539 （たとえば https://www.amazon.co.jp/dp/B09DYTRPZ7/ ）
[100個850円程度] 可変抵抗（可変じゃなくて1Mオームの固定抵抗でも可）（たとえば https://www.amazon.co.jp/dp/B0B8M91D3T/ ）
[10個900円程度] DC電源コネクタ（たとえば https://www.amazon.co.jp/dp/B077GV4NVY/ ）

picoを1個、L298Nを2個、アダプタ2個、CdSを1個、可変抵抗を1個、コネクタを2個、合計6030円程度。
もしpicoや電源アダプタは他でも活用できて転用可能なので、これを費用に含めないとすれば、1230円程度ということになります！

↑

(3) ポイント制御

TOMIX の N-PL541-15(F)で実験（番号は1272）。 https://www.amazon.co.jp/dp/B001V7YC6Y/
6.0Vを32ミリ秒だけ印加すると切り替わりました。5.0Vにすると秒数にかかわらず無反応になり、6.0Vでも16ミリ秒とかにすると切り替わりが不安定になりました。
これを踏まえて、「7.5Vを48ミリ秒印加する」という設定を本番では使おうと思います。

[参考]
- 12V, 200～300ミリ秒が良いという説 : https://inoyoshio.muragon.com/entry/233.html
- 純正パワーユニットは18.5Vとコンデンサで切り替えしているという解析記事 : https://rtmrw.parallel.jp/laboratory4/lab-report-88/lab-88.html
- ポイント手動切り替え回路の説明 : https://ngauge.jp/point-sw_1/

↑

(4) 電車の制御

12V PWM=144/255 でノロノロと動き始めるが、これは厳密には車両や進行方向によって異なる。